$Title Solow Model
*@K.R.Bbattarai, Business School, University of Hull, UK.
set t  time /t1*t400/
tfirst 
tlast;

tfirst(t) = Yes$(ord(t) eq 1);

tlast(t) = Yes$(ord(t) eq card(t));

alias (t, tt);

PARAMETERS 
a  capital share
b  labour share
d  depreciation rate
n  population growth rate
s  savings rate
L0  initial population
K0  initial capital stock
L(t) lablour
;

a=0.3;
b = 1-a;
d=0.03;
n=0.02;
s=0.2;
l0=100;
k0=100;
L(t) =L0$tfirst(t)+((1+n)**ORD(T)*L0)$(ord(t) ne 1);

Variables
Y(t)  output
Sv(t) savings
I(t)  investment
C(t)  consumption
DP(t) depreciation
K(t)  capital stock
CT    total consumption
;

Equations
output(t)  output
saving(t)  saving
invest(t)  investment
consump(t) consumption
tcons      total consumption
depr(t)    depreciation
capital(t) capital stock
;

output(t)..

y(t) =e= (k(t)**A)*L(t)**b;

saving(t)..

Sv(t) =e=s*Y(t);

invest(t)..

I(t) =e= (n+d)*K(t);

consump(t)..

C(t) =e=Y(t)-Sv(t);

depr(t)..

DP(t) =e= d*K(t);

capital(t)..

K(t) =e= K0$tfirst(t)+((1-d)*K(t-1)+Sv(t-1)-I(t-1))$(ord(t) ne 1);

tcons..
ct =e=sum(t,c(t));

Model solow/output,saving,invest,consump,tcons,depr,capital/;

solve solow maximising CT using nlp;

Parameter report;
report(t,"capital") = K.L(t);
report(t,"LABOUR") = L(T);
report(t,"output") = Y.L(t);
report(t,"SAVING") = SV.L(t);
report(t,"DEPR") = DP.L(t);
report(t,"INVEST") = I.L(t);
report(t,"CONSUMP") = C.L(t);
report(t,"NET INV") = Sv.L(t)-I.L(t);

DISPLAY REPORT;